spiderplot

Spider plots are essentially parallel axis plots in which the axes are arranged radially rather than vertically. Such plots are sometimes called radar charts. In gnuplot this requires working within a coordinate system established by the command set spiderplot, analogous to set polar except that the angular coordinate is determined implicitly by the parallel axis number. The appearance, labelling, and tic placement of the axes is controlled by set paxis. Further style choices are controlled using set style spiderplot, set grid, and the individual components of the plot command.

Because each spider plot corresponds to a row of data rather than a column, it would make no sense to generate key entry titles in the normal way. Instead, if a plot component contains a title the text is used to label the corresponding axis. This overrides any previous set paxis n label "Foo". To place a title in the key, you can either use a separate keyentry command or extract text from a column in the input file with the key(column) using specifier. See keyentry, using key.

In this figure a spiderplot with 5 axes is used to compare multiple entities that are each characterized by five scores. Each line (row) in $DATA generates a new polygon on the plot.

     $DATA << EOD
              A      B      C      D      E      F
     George  15     75     20     43     90     50
     Harriet 40     40     40     60     30     50
     EOD
     set spiderplot
     set style spiderplot fs transparent solid 0.2 border
     set for [p=1:5] paxis p range [0:100]
     set for [p=2:5] paxis p tics format ""
     set             paxis 1 tics font ",9"
     set for [p=1:5] paxis p label sprintf("Score %d",p)
     set grid spiderplot
     plot for [i=1:5] $DATA using i:key(1)